- XFRX ships with its own report previewer. The previewer allows for:
- Directing the report generation to the previewer or to preview an existing XFF file
- Searching the document
- Exporting the document to any of the supporting output formats
- Printing the document
- Navigation via hyperlinks and bookmarks
- Invoking FoxBase code on hyperlink click (custom events)
The previewer is implemented as a container object, so it can be very easily added inside any VFP form.
XFF files don’t have to be stored as physical files. You can also create temporary XFF files that will be automatically released when you close the previewer. (Please see Creating temporary XFF files on page 45 for more information).
Table of Contents |
---|
Setting up the XFRX previewer
Info |
---|
This section has been added to reflect changes in XFRX ver. 11.3. If you are using previous XFRX versions, please see Using XFCont class paragraph below in this chapter. |
There are several ways how you can setup the XFRX previewer. You can either use the already prepared standalone previewing component or start with the basic classes of the previewer component to add the previewing capabilities to your own forms.
The following subchapters describe using three classes implemented in XFRXLIB.VCX which you can use as a starting point to implement the XFRX previewer in your application:
| frmMPPreviewer | cntXFRXMultiPage | XFCont |
Implemented as a form (the easiest setup) | Yes | No | No |
Implemented as a container (can be embedded into existing forms) | No | Yes | Yes |
supports multi-tab interface | Yes | Yes | No |
supports embedded toolbar | Yes | Yes | No |
- XFCont is the basic XFRX previewer class. It is implemented as a container object and supports searching, hyperlinks, bookmarks, printing and exporting.
- cntXFRXMultiPage class extends the XFCont class functionality with multi-tab interface – it can display multiple previewer tabs in a page frame class. It also supports a (fake) embedded toolbar, which is a toolbar-like control at the top of the container, which is very useful if the previewer form is not inside the main VFP screen.
- frmMPPreviewer is a form class that implements cntXFRXMultiPage and serves as a “proxy” to the cntXFRXMultiPage class features. If all you need is a full screen report previewer, this one is the easiest to setup.
Default settings
A new object-type property has been added to the XFCont, cntXFRXMultipage and frmMPPreviewer classes: oDisplayDefaults. It has the following properties:
- StartingPage (integer) - the 1st page to show in the previewer. Default value is 1.
- DefaultOutputFileName (string) - the default output file name when exporting from the previewer
- PagesPerSheet (string) - encoded pages per sheet layout value. Default value: 1x1. Allowed values: 1x1, 2x1, 2x2, 3x1, 3x2, 4x2.
- ZoomFactor (integer) - the zoom factor. default value = 100. -1 = fit to width, -2 = fit page. The zoom factor will be used only of PagesPerSheet is 1x1, otherwise it defaults to -2.
Code Block |
---|
loPreview = CREATEOBJECT("frmMPPreviewer")
loPreview.oDisplayDefaults.StartingPage = 2
loPreview.oDisplayDefaults.DefaultOutputFileName = "invoice15_09"
loPreview.oDisplayDefaults.ZoomFactor = -1
loPreview.oDisplayDefaults.PagesPerSheet = "1x1"
loPreview.PreviewXFF(loXFF)
loPreview.show(1) |
Common methods and properties
Even though you can use different classes to provide the previewing capabilities in your application, all classes share most of the properties and methods you can use to control and customize them.
Controlling multi-tab preview features
Info |
---|
The properties and methods described in this paragraph are implemented in cntXFRXMultiPage and frmMPPreviewer classes. The multi-tab features are not implemented in XFCont class. |
Property / Method | Usage |
lShowTabForOneReport (property) | Possible values:
|
PreviewXFF (method) | Syntax: PreviewXFF(toXFF, tcCaption, tnPageNo) Call this method to preview the XFF file in the previewer. You can call this method multiple times, which would either add new reports as new pages or replace existing pages, depending on parameters. Parameters: toXFF The reference of a XFF file that is going to be previewed tcCaption (optional) The caption of the page with this report if previewing multiple reports. tnPageNo(optional) The page on which the XFF file is going to be previewed. If this parameter is empty or greater than the number of existing pages, a new page is added. If a page with this number already exists, it will be replaced. |
RemovePage (method) | Syntax: RemovePage(tnPageNo) Removes a page from the previewer. Parameters: tnPageNo (optional) The number of the page to remove. If the parameter is empty or the number is greater than the number of existing pages, the last one is removed. |
Registering an extension handler
The extension handler allows for extending the functionality of the basic classes without need of creating subclasses. All you need is to create a custom class, which implements certain methods. The custom class is registered with the XFRX previewer class (using SetExtensionHandler method) and the previewer calls the extension methods on appropriate events.
Currently supported event methods are:
Method | Usage |
---|---|
BeforeExport | The method is executed right before the report is exported to the output format and can be used to parametrize the xfrx session object before exporting. Parameters: toXFF – the handler of the XFF file that is being previewed toParameters – the object containing the export options
|
AfterExport | The method is executed right after the report is exported to the output format and can be used to copy output file to another folder. Parameters:toXFF – the handler of the XFF file that is being previewed toParameters – the object containing the export options
|
Export | This method is called when the Export button is clicked in the toolbar. Parameters: toXFF – the handler of the XFF file that is being previewed |
ExportOptions | This method is called after the Export Options dialog is closed, before the actual Export is executed Parameters: toXFF – the handler of the XFF file that is being previewed toParameters – the object containing the export options |
This method is called when the Print button is clicked in the toolbar. Parameters: toXFF – the handler of the XFF file that is being previewed | |
PrintOptions | This method is called after the Printer Options dialog is closed, before the actual print. Parameters: toXFF – the handler of the XFF file that is being previewed toParameters – the object containing the print options |
KeyPress | This method is called from KeyPress() method od xfcont class. Parameters: toXFF – the handler of the XFF file that is being previewed nKeyCode – Contains a number that identifies the key pressed nShiftAltCtrl - Sets a particular bit if a modifier key is held down while pressing the key specified by nKeyCode
|
Code Block | ||||||
---|---|---|---|---|---|---|
| ||||||
USE invoices ORDER customer
LOCAL loSession, lnRetval, loXFF, loPreview, loScripts
loSession=EVALUATE([xfrx("XFRX#LISTENER")])
lnRetVal = loSession.SetParams("",,,,,,"XFF") && no name = just in memory
IF lnRetVal = 0
REPORT FORM invoices OBJECT loSession
loXFF = loSession.oxfDocument
*
* initialize the previewer
*
SET CLASSLIB TO xfrxlib ADDITIVE
loPreview = CREATEOBJECT("frmMPPreviewer")
loPreview.setExtensionHandler(CREATEOBJECT("MyExtensionHandler"))
loPreview.windowType = 0
loPreview.iBook = 0
loPreview.PreviewXFF(loXFF)
loPreview.show(1)
ENDIF
DEFINE CLASS MyExtensionHandler AS Custom
PROCEDURE Export
LPARAMETERS toXFF
IF USED("_xfExportTypes")
USE IN _xfExportTypes
ENDIF
*
* define my export options list
*
CREATE CURSOR _xfExportTypes (name C(50), extension C(4), targetCode C(10))
INSERT INTO _xfExportTypes VALUES ("HTML", "html", "HTML")
INSERT INTO _xfExportTypes VALUES ("PDF", "pdf", "PDF")
INSERT INTO _xfExportTypes VALUES ("Excel", "xls", "XLS")
ENDPROC
PROCEDURE ExportOptions
LPARAMETERS toXFF, toOptions
IF toOptions.cTarget = "XLS"
*
* my own code to handle output to Excel
*
=MESSAGEBOX("exporting to "+toOptions.cOutputFile)
RETURN .F. && suppress the default behavior
ELSE
RETURN .T. && continue with the default behavior
ENDIF
ENDPROC
ENDDEFINE |
Code Block | ||||||
---|---|---|---|---|---|---|
| ||||||
SET PATH TO xfrxlib
SET CLASSLIB TO xfrxlib
LOCAL loPreview, loSession, loExtensionHandler
loExtensionHandler = CREATEOBJECT("myExtensionHandler")
loPreview = CREATEOBJECT("frmMPPreviewer")
loSession=EVALUATE([xfrx("XFRX#LISTENER")])
*
* create a memory XFF file
*
lnRetVal = loSession.SetParams(,,,,,,"XFF")
IF lnRetVal = 0
SELECT * ;
FROM customers JOIN orders ON customers.customerid = orders.customerid ;
JOIN orderdetails ON orders.orderid = orderdetails.orderid ;
order by customers.companyname, customers.customerID, orders.orderID ;
INTO CURSOR custlist
REPORT FORM custlist OBJECT loSession
ENDIF
*
* assign the extension handler
*
loPreview.setExtensionHandler(loExtensionHandler)
*
* preview the report
*
loPreview.previewXFF(loSession.oxfdocument)
loPreview.show(1)
DEFINE CLASS myExtensionHandler as Custom
PROCEDURE Print
LPARAMETERS toXFF
RETURN .t. && continue with the default behavior
ENDPROC
PROCEDURE Export
LPARAMETERS toXFF
*
* now you can process the XFF file
*
RETURN .F. && override the default behavior
ENDPROC
ENDDEFINE |
Code Block | ||||||
---|---|---|---|---|---|---|
| ||||||
use demoreps\invoices order customer
local loSession, lnRetval, loXFF, loPreview, loScripts
loSession=EVALUATE([xfrx("XFRX#LISTENER")])
lnRetVal = loSession.SetParams(,,,,,,"XFF") && no name = just in memory
If lnRetVal = 0
REPORT FORM demoreps\invoices object loSession
*
* the XFRX#DRAW object reference is stored in oxfDocument property
*
loXFF = loSession.oxfDocument
*
* initialize the previewer
*
SET PATH TO xfrxlib
SET CLASSLIB TO xfrxlib ADDITIVE
loPreview = CREATEOBJECT("frmMPPreviewer")
*
* setup the extension handler
*
loPreview.oExtensionHandler = CREATEOBJECT("SampleExtensionHandler")
loPreview.windowtype = 1
loPreview.iTool = 2 && embedded toolbar
loPreview.PreviewXFF(loXFF)
loPreview.show(1)
ENDIF
DEFINE CLASS SampleExtensionHandler as Custom
PROCEDURE BeforeExport
LPARAMETERS toSession, toExportParameters
toSession.setAuthor("Martin") && set the document author property
IF toExportParameters.cTarget = "XLS" && (XLS or XLSPLAIN)
toSession.SetOtherParams("DISPLAY_GRID_LINES",.F.) && do not display gridlines in excel
ENDIF
ENDPROC
PROCEDURE AfterExport
LPARAMETERS toSession, toOptions
IF toOptions.cTarget = "XLS"
*COPY FILE (toOptions.coutputfile) TO ([anybackupfolder]\[anyfile.xls])
ENDIF
ENDPROC
ENDDEFINE |
Code Block | ||||
---|---|---|---|---|
| ||||
use demoreps\invoices order customer
local loSession, lnRetval, loXFF, loPreview, loScripts
loSession=EVALUATE([xfrx("XFRX#LISTENER")])
lnRetVal = loSession.SetParams(,,,,,,"XFF") && no name = just in memory
If lnRetVal = 0
REPORT FORM demoreps\invoices object loSession
*
* the XFRX#DRAW object reference is stored in oxfDocument property
*
loXFF = loSession.oxfDocument
*
* initialize the previewer
*
SET PATH TO xfrxlib
SET CLASSLIB TO xfrxlib ADDITIVE
loPreview = CREATEOBJECT("frmMPPreviewer")
*
* setup the extension handler
*
loPreview.oExtensionHandler = CREATEOBJECT("SampleExtensionHandler")
loPreview.windowtype = 1
loPreview.iTool = 2 && embedded toolbar
loPreview.PreviewXFF(loXFF)
loPreview.show(1)
ENDIF
DEFINE CLASS SampleExtensionHandler as Custom
PROCEDURE KeyPress(loXFCont, nKeyCode, nShiftAltCtrl)
* hotkey for print P (112-p, 80-P)
IF INLIST(nKeyCode, 112, 80)
loXFCont.Print()
ENDIF
ENDPROC
ENDDEFINE
|
Showing / hiding bookmarks
The bookmark panel behavior is controlled by the iBook property:
Property | Usage |
iBook | Controls if the bookmark should be displayed in the previewer. The allowed values are:
|
Showing / hiding previewer toolbars
There are two toolbars in the previewer control – one is placed at the bottom of the control, the other one is available as a floating toolbar panel, which by default docks at the top of the main window, or, alternatively, as an “embedded toolbar”. All three classes implement iTool and ShowStatus properties that control visibility of the toolbars:
Property | Usage |
classMainToolbar | The class name of the toolbar. The default value is “xfrxToolbar”. You can create a child of the default xfrxToolbar class (defined in xfrxlib.vcx) and use this property to instruct the previewer to use your class rather than the default one. This property works for the “real” toolbar – if iTool property is 0 or 1. if iTool is set to 2, cmdEmbeddedToolbar container class is used as the “embedded” toolbar. |
iTool | Controls the visibility of the toolbar at the top. The allowed values are:
|
ShowStatus | Controls the visibility of the toolbar at the status bar of the previewer container. The allowed values are:
|
Displaying progress bar
Property | Usage |
oprogress | The object instance of XFRX progress bar |
Code Block |
---|
use demoreps\invoices order customer
local loSession, lnRetval, loXFF, loPreview, loScripts
loSession=EVALUATE([xfrx("XFRX#LISTENER")])
lnRetVal = loSession.SetParams(,,,,,,"XFF") && no name = just in memory
If lnRetVal = 0
REPORT FORM demoreps\invoices object loSession
*
* the XFRX#DRAW object reference is stored in oxfDocument property
*
loXFF = loSession.oxfDocument
*
* initialize the previewer
*
SET PATH TO xfrxlib
SET CLASSLIB TO xfrxlib ADDITIVE
loPreview = CREATEOBJECT("frmMPPreviewer")
*
* setup the extension handler
*
loPreview.oExtensionHandler = CREATEOBJECT("SampleExtensionHandler")
loPreview.oprogress=createobject("progress")
loPreview.PreviewXFF(loXFF)
loPreview.show(1)
ENDIF
define class progress as custom
procedure updateProgress
lpara ta,tb, tc
wait window nowait "Page #: "+allt(str(tb))+" Report #: "+allt(str(ta))+" ("+allt(str(tc))+"%)"
enddef
|
Using frmMPPreviewer class
This class serves as a standalone (fullscreen) previewer window. All you need to do to make it work is to pass it a reference to the XFF file to preview, using the previewXFF method, as described in Controlling multi-tab preview features paragraph above. (If you are not sure how to create a XFF file reference, please read chapters 16.2: Initializing the XFRX#DRAW class instance and 16.3: Creating temporary XFF files). Here is a very simple “Hello World” example:
Code Block |
---|
SET CLASSLIB TO XFRXLIB.VCX ADDITIVE
loPreview = CREATEOBJECT("frmMPPreviewer") && create the previewer object
toViewer.previewXFF(loXFF) && loXFF is XFF file reference
loPreview.show(1) && show the form as modal |
Info |
---|
Make sure to set all properties (like iTool, ShowStatus, etc.) before you call PreviewXFF(…) otherwise they won’t be used. |
Using cntXFRXMultiPage class
- Add an instance of cntXFRXMultiPage class (of XFRXLIB.VCX) into your form. Adjust the size of the cntXFRXMultiPage class object container as you need. The previewer, including the status bar, icons and scroll bars will be displayed in the container. If you resize the container in runtime, its content is automatically adjusted.
When the form is about to be released, the cntXFRXMultiPage class instance needs to do some cleanup. To enable that please call the class instance’s clearLink() method from form’s destroy method:
Code Block procedure Destroy thisform.cntXFRX.clearLink() endproc
When running the form, make sure the XFRXLIB.VCX class library is referenced in SET CLASSLIB command:
Code Block SET CLASSLIB TO XFRXLIB.VCX ADDITIVE
- Call the PreviewXFF method to preview a XFF file, as described in Controlling multi-tab preview features paragraph above.
- By default, cntXFRXMultiPage is using an instance of the XFCont class for each page. Should you like to make it use a different class (eg. a subclass of XFCont) put the class name to the ClassPreviewPage property of the cntXFRXMultiPage instance.
Using XFCont class
- Add an instance of XFCONT class (of XFRXLIB.VCX) into your form. Adjust the size of the XFCONT class container as you need. The previewer, including the status bar, icons and scroll bars will be displayed in the container. If you resize the container in runtime, its content is automatically adjusted.
When the form is about to be released, the XFCONT class instance needs to do some cleanup. To enable that please call the XFCont class instance’s clearLink() method from form’s destroy method:
Code Block procedure Destroy thisform.cntXFRX.clearLink() endproc
When running the form, make sure the XFRXLIB.VCX class library is referenced in SET CLASSLIB command:
Code Block SET CLASSLIB TO XFRXLIB.VCX ADDITIVE
VFP 8.0 approach
In VFP 8.0, there are two options how to preview report in the previewer. The options differ in the calling mechanism, although internally they both work exactly the same.
15.1.5.1.1 Generating the “CNT” output type
The approach is using the standard syntax of calling XFRX, without explicitly using the XFRX#DRAW class (although it is used in the background). You cannot open an existing XFF file with this approach – you always need to run a report that will be previewed.
- Do not send anything as the output file name
- Use “CNT” as the output type parameter in the SetParams method call
- Call Reset method of the previewer container class
- Call SetOtherParams method of the XFRXSession class instance with the reference of XFCont instance as a parameter
Example:
Code Block | ||||
---|---|---|---|---|
| ||||
local loSession, lnRetval
loSession= xfrx("XFRX#INIT")
lnRetVal = loSession.SetParams(,,,,,,"CNT")
IF lnRetVal = 0
*
* we are assuming the XFCont container is
* available as thisform.cntXFRX
*
thisform.cntXFRX.reset()
loSession.setotherparams(thisform.cntXFRX)
loSession.ProcessReport("report")
loSession.finalize()
ENDIF |
Using the XFRX#DRAW class
The advantage of this method is that you can preview an existing XFF file – the XFF file is opened and “converted” to “CNT” output type via the TransformReport method:
Example:
Code Block | ||||
---|---|---|---|---|
| ||||
LOCAL loSession
loSession= xfrx("XFRX#INIT")
loReport = xfrx("XFRX#DRAW")
IF thisform.oReport.openDocument("file.xff")
thisform.cntXFRX.reset()
lnRetVal = loSession.SetParams(,,,,,,"CNT")
IF lnRetVal = 0
loSession.setOtherParams(thisform.cntXFRX)
loSession.TransformReport(thisform.oReport)
ENDIF
ENDIF |
VFP 9.0 Approach
In VFP 9.0 the logic is the same, just the syntax is a little bit different – the reference to the XFCont object is copied to XFRXPreviewer property of the XFRXListener class instance and then previewReport method with the XFRX#DRAW reference as parameter is called:
Code Block | ||||
---|---|---|---|---|
| ||||
LOCAL loSession
loSession= xfrx("XFRX#LISTENER")
thisform.oReport = xfrx("XFRX#DRAW")
IF thisform.oReport.openDocument("file.xff")
thisform.cntXFRX.reset()
loSession.XFRXPreviewer = thisform.cntXFRX
loSession.previewReport(thisform.oReport)
ENDIF |
Hyperlink decoration
A new property has been added to the XFCont, cntXFRXMultipage and frmMPPreviewer classes: UnderlineHyperlinksOnPrint. You can use the following values:0 - no decoration for hyperlinks
1 - display "normal" hyperlinks in blue, but do not decorate custom event hyperlinks (green)
2 - (default value) decorate both blue and green hyperlinks
To support this in the print output, the PrintDocument method of the XFRX#DRAW class has a new parameter, tnUnderlineHyperlinksOnPrint, with the same values and logic.
Custom buttons
This feature is implemented using the extension handler mechanism: A new method is now supported - ToolbarOnInit, which is invoked at the time the toolbar is initialized. In this method the extension handler can add new buttons to the previewer and their click events can be bound with other methods in the extension handler. A new property is now supported, too - oPreviewContainer. If it is available, the previewer will automatically fill it with the XFCont object reference for easier access to the previewer properties in the custom buttons click event methods.
Example:
Code Block | ||||
---|---|---|---|---|
| ||||
use demoreps\sales
local loSession, lnRetval, loXFF, loPreview, loScripts
loSession=EVALUATE([xfrx("XFRX#LISTENER")])
lnRetVal = loSession.SetParams(,,,,,,"XFF") && no name = just in memory
IF lnRetVal = 0
REPORT FORM demoreps\sales object loSession
*
* the XFRX#DRAW object reference is stored in oxfDocument property
*
loXFF = loSession.oxfDocument
*
* initialize the previewer
*
SET PATH TO xfrxlib
SET CLASSLIB TO xfrxlib ADDITIVE
loPreview = CREATEOBJECT("frmMPPreviewer")
*
* setup the extension handler
*
loPreview.oExtensionHandler = CREATEOBJECT("SampleExtensionHandler")
loPreview.windowtype = 1
loPreview.iTool = 2 && embedded toolbar
* loPreview.iTool = 1 && standard toolbar
loPreview.PreviewXFF(loXFF)
loPreview.show(1)
ENDIF
DEFINE CLASS SampleExtensionHandler as Custom
oPreviewContainer = null
PROCEDURE ToolbarOnInit
LPARAMETERS toToolbar
LOCAL button
IF toToolbar.AddObject("mybutton", "commandbutton")
BINDEVENT(toToolbar.mybutton, "click" , this, "ButtonClicked")
toToolbar.mybutton.tabindex = 1
toToolbar.mybutton.Visible = .t.
IF UPPER(totoolbar.BaseClass)!="TOOLBAR"
toToolbar.mybutton.left = toToolbar.cmdQuit.left
toToolbar.cmdQuit.left = toToolbar.mybutton.left + toToolbar.mybutton.width
ENDIF
ENDIF
ENDPROC
PROCEDURE ButtonClicked
LOCAL lcString
lcString = "this.oPreviewContainer.Name: "+this.oPreviewContainer.Name+CHR(13)
lcString = lcString + "current page: "+TRANSFORM(this.oPreviewContainer.nPageNo)+CHR(13)
lcString = lcString + "XFRX#DRAW Object: "+this.oPreviewContainer.oXFRXWriter.Name+CHR(13)
lcString = lcString + "Page count: "+TRANSFORM(this.oPreviewContainer.oXFRXWriter.PageCount)+CHR(13)
WAIT WINDOW lcString
* this.oPreviewContainer.oXFRXWriter.PrintDocument(...)
* this.oPreviewContainer.oXFRXWriter.SavePicture(...)
ENDPROC
ENDDEFINE |
Printing from the previewer
By default, when users click the “Print” button in the previewer toolbar (), the Print method of the XFCont class is called. This method displays a dialog box with a printer selection and allows for entering a page range:
When a XFF file is previewed, the corresponding XFRX#DRAW reference is accessible via oXFRXWriter property of the previewer class instance.
If you would like to change the way the previewer reacts to the print event, you can either setup an extension handler (please see Registering an extension handler paragraph above in this chapter for more information) or you can override the Print method, create your own printing dialog and then run XFRX#DRAW’s printDocument method. The source code of XFCont class is available so you can use the current Print method as a template.
The printer job name generated by the Print method is stored in cJobName property of the XFCont class and can be changed both in design time and runtime. (The default value is “XFRX”).
See also: Printing XFF files chapter on page 46 for more information about printing the content of XFF files.
Exporting reports from the previewer
Similarly to printing, when users click the “Export” button in the previewer toolbar (), the Export method of the XFCont class is called. This method displays a dialog box with output type and a file name selection and converts the XFF file that is being previewed to the output document:
If you would like to create your own custom exporting solution, you can either setup an extension handler (please see Registering an extension handler paragraph above in this chapter for more information) or you can create a child of the XFCont class and override the Export method.
E-mail support in the XFRX previewer
An email icon has been added to the XFRX previewer toolbar. It is disabled by default for backward compatibility and can be enabled by setting the iEmail property of the previewer class [xfCont, cntXFRXMultiPage or frmMPPreviewer] to 1. If you click the email icon, it runs the Email method of the xfCont class. By default it displays a simple dialog box asking for email address, subject, body, etc. and uses VFPWinsock library to send the email.
Info |
---|
VFPWinsock is a free SMTP sendmail library written by a VFP MVP Francis Faure. It is not distributed together with XFRX and it can be downloaded fromhttp://www.xfrx.net/vfpWinsock/index_e.asp. It is a nice little package written in VFP distributed as a single .prg. |
- Email - the event is fired when the icon is clicked, before the dialog is displayed. XFF file reference is sent as the 1st parameter. Returning .F. will suppress the default behavior.
- EmailOptions - this event is fired after the dialog is displayed and user clicked "Send". XFF file reference and options object is sent as a parameter. Returning .F. will suppress the email to be sent
The parameter object has the following properties:
- cTo
- cCC
- cBCC
- cSubject
- cAttachmentName
- cBody
Following are sample of the two most common scenarios:
Suppress the default behavior and handle the email event on your own
Code Block | ||||
---|---|---|---|---|
| ||||
loPreview = CREATEOBJECT("frmMPPreviewer")
loPreview.iEmail = 1 && show the email icon
loPreview.oExtensionHandler = CREATEOBJECT("SampleExtensionHandler")
loPreview.PreviewXFF(loXFF) && preview the document
loPreview.show(1)
DEFINE CLASS SampleExtensionHandler as Custom
PROCEDURE Email
LPARAMETERS loXFF
LOCAL loSession, lcFileName
loSession=EVALUATE([xfrx("XFRX#INIT")])
lcFileName = Addbs(Sys(2023))+"test.pdf" && temporary file name
IF loSession.SetParams(lcFileName,,.T.,,,,"PDF") = 0 && the 3rd parameter says we do not want to preview the PDF
loSession.TransformReport(loXFF)
LOCAL sm
SET PROCEDURE TO vfpwinsock ADDITIVE
sm = Createobject("vfp_winsock_send_mail")
sm.smtp_host = "your.smtp.server.here" &&&<<<<<<<<<<<<<<<<<<<< put your smtp server here
sm.From = "eqeus@eqeus.com"
sm.To = "eqeus@eqeus.com"
sm.subject = "Email test"
sm.silence = .T.
sm.attaCHMENT = lcFileName
IF !sm.Send()
=MESSAGEBOX(sm.erreur,16,"xfrx test")
ELSE
=MESSAGEBOX("Message was sent",0,"xfrx test")
ERASE (lcFileName)
ENDIF
ENDIF
RETURN .F.
ENDPROC
ENDDEFINE |
Code Block | ||||
---|---|---|---|---|
| ||||
DEFINE CLASS SampleExtensionHandler as Custom
PROCEDURE EmailOptions
LPARAMETERS loXFF, loOptions
loOptions.cSMTP_HOST = "mail.your_domain.com"
loOptions.cFrom = "eqeus@eqeus.com"
ENDPROC
ENDDEFINE |
Previewer localization
Each localization is stored in two files:
- XFRXLIB_<localization_code>.dbf - strings translation
- XFRXLIB_<localization_code>.vcx - find and page selection dialogs localization
To create a new localization, please follow these steps:
- Choose a code for your localization (e.g. DE for German)
- Create a copy of default localization DFB (localization\default\XFRXLIB_XXX.DBF (+CDX, +FPT)). Change the suffix according to your localization code. The default localization DBF contains English strings that need to be translated.
Create XFRXLIB_<localization_code>.vcx visual class library using localization\default\locClass.prg. Send the localization code as a parameter.
Example: Copy locClass to the XFRXLIB directory and call:Code Block do locClass with "DE"
which will create the XFRXLIB_DE class library. Translate the two dialog classes in the class library.
- Copy the localization files to XFRXLIB directory.
To activate the localization in your code, call setLanguage method of XFCont class. Send the localization code as a parameter.
Example:
Child pages (Children Display) |
---|