Page Comparison

Info
This section has been added to reflect changes in XFRX ver. 11.3. If you are using previous XFRX versions, please see Using XFCont class paragraph below in this chapter.

There are several ways how you can setup the XFRX previewer. You can either use the already prepared standalone previewing component or start with the basic classes of the previewer component to add the previewing capabilities to your own forms.

The following subchapters describe using three classes implemented in XFRXLIB.VCX which you can use as a starting point to implement the XFRX previewer in your application:

	frmMPPreviewer	cntXFRXMultiPage	XFCont
Implemented as a form (the easiest setup)	Yes	No	No
Implemented as a container (can be embedded into existing forms)	No	Yes	Yes
supports multi-tab interface	Yes	Yes	No
supports embedded toolbar	Yes	Yes	No

XFCont is the basic XFRX previewer class. It is implemented as a container object and supports searching, hyperlinks, bookmarks, printing and exporting.
cntXFRXMultiPage class extends the XFCont class functionality with multi-tab interface – it can display multiple previewer tabs in a page frame class. It also supports a (fake) embedded toolbar, which is a toolbar-like control at the top of the container, which is very useful if the previewer form is not inside the main VFP screen.
frmMPPreviewer is a form class that implements cntXFRXMultiPage and serves as a “proxy” to the cntXFRXMultiPage class features. If all you need is a full screen report previewer, this one is the easiest to setup.

Default settings

A new objects-type property has been added to the XFCont, cntXFRXMultipage and frmMPPreviewer classes:

Name	Description	XFRX version
cImageFolder	Folder with images for XFRX preview.	16.1.4
oDisplayDefaults	Display default options.
oPrinterOptions	Print default options.	17.0.0
oExportOptions	Export default options.	17.0.0
oEmailOptions	E-mail default options.	17.0.0
lVFP8	Switch for backware compatibility with previous VFP versions in VFP 9.0. Default value is .F.	17.3.1

Object oDisplayDefaults has the following properties:

Name	Type	Description	XFRX version
StartingPage	integer	The 1st page to show in the previewer. Default value is 1.
DefaultOutputFileName	string	The default output file name when exporting from the previewer.
PagesPerSheet	string	Encoded pages per sheet layout value. Default value: 1x1. Allowed values: 1x1, 2x1, 2x2, 3x1, 3x2, 4x2.
ZoomFactor	integer	the zoom factor. default value = 100. -1 = fit to width, -2 = fit page. The zoom factor will be used only of PagesPerSheet is 1x1, otherwise it defaults to -2.
FindColor	integer	background color of searched text	17.0.0

Example:

Code Block

linenumbers	true

m.loPreview = CREATEOBJECT("frmMPPreviewer")
m.loPreview.oDisplayDefaults.StartingPage = 2
m.loPreview.oDisplayDefaults.DefaultOutputFileName = "invoice15_09"
m.loPreview.oDisplayDefaults.ZoomFactor = -1
m.loPreview.oDisplayDefaults.PagesPerSheet = "1x1"
m.loPreview.lVFP8=.T. && don't use XFRX#LISTENER
m.loPreview.PreviewXFF(loXFF)
m.loPreview.show(1)

Common methods and properties

Even though you can use different classes to provide the previewing capabilities in your application, all classes share most of the properties and methods you can use to control and customize them.

Controlling multi-tab preview features

Info
The properties and methods described in this paragraph are implemented in cntXFRXMultiPage and frmMPPreviewer classes. The multi-tab features are not implemented in XFCont class.

Property / Method

Usage

lShowTabForOneReport

(property)

Possible values:

.F. (default) – the tab with page captions is hidden if only one report is previewed. It will became automatically visible when the second report gets previewed.
.T. – the tab with page captions is always visible.

PreviewXFF

(method)

Syntax:

PreviewXFF(toXFF, tcCaption, tnPageNo)

Call this method to preview the XFF file in the previewer. You can call this method multiple times, which would either add new reports as new pages or replace existing pages, depending on parameters.

Parameters:

toXFF

The reference of a XFF file that is going to be previewed

tcCaption (optional)

The caption of the page with this report if previewing multiple reports.

tnPageNo(optional)

The page on which the XFF file is going to be previewed. If this parameter is empty or greater than the number of existing pages, a new page is added. If a page with this number already exists, it will be replaced.

RemovePage

(method)

Syntax:

RemovePage(tnPageNo)

Removes a page from the previewer.

Parameters:

tnPageNo (optional)

The number of the page to remove. If the parameter is empty or the number is greater than the number of existing pages, the last one is removed.

Registering an extension handler

The extension handler allows for extending the functionality of the basic classes without need of creating subclasses. All you need is to create a custom class, which implements certain methods. The custom class is registered with the XFRX previewer class (using SetExtensionHandler method) and the previewer calls the extension methods on appropriate events.

Currently supported event methods are:

Method

Usage

Comment

KeyPress

This method is called from KeyPress() method od xfcont class.

Parameters:

toXFF – the handler of the XFF file that is being previewed

nKeyCode – Contains a number that identifies the key pressed

nShiftAltCtrl - Sets a particular bit if a modifier key is held down while pressing the key specified by nKeyCode

Code Block

language	vb
title	Example 1: Defining the export output options list, intercepting the XLS export
linenumbers	true

USE invoices ORDER customer
LOCAL m.loSession, m.lnRetval, m.loXFF, m.loPreview, m.loScripts
m.loSession=EVALUATE([xfrx("XFRX#LISTENER")])
m.lnRetVal = m.loSession.SetParams("",,,,,,"XFF") && no name = just in memory
IF m.lnRetVal = 0
   REPORT FORM invoices OBJECT m.loSession
   m.loXFF = m.loSession.oxfDocument
   *
   * initialize the previewer
   *
   SET CLASSLIB TO xfrxlib ADDITIVE
   m.loPreview = CREATEOBJECT("frmMPPreviewer")
   m.loPreview.setExtensionHandler(CREATEOBJECT("MyExtensionHandler"))
   m.loPreview.windowType = 0
   m.loPreview.iBook = 0
   m.loPreview.PreviewXFF(loXFF)
   m.loPreview.show(1)
ENDIF
 
 
DEFINE CLASS MyExtensionHandler AS Custom
 
   PROCEDURE Export
      LPARAMETERS m.toXFF
      IF USED("_xfExportTypes")
         USE IN _xfExportTypes
      ENDIF
      *
      * define my export options list
      *
      CREATE CURSOR _xfExportTypes (name C(50), extension C(4), targetCode C(10))
      INSERT INTO _xfExportTypes VALUES ("HTML",  "html",  "HTML")
      INSERT INTO _xfExportTypes VALUES ("PDF",   "pdf",   "PDF")
      INSERT INTO _xfExportTypes VALUES ("Excel", "xls",   "XLS")
   ENDPROC
 
   PROCEDURE ExportOptions
      LPARAMETERS m.toXFF, m.toOptions
      IF m.toOptions.cTarget = "XLS"
         *
         * my own code to handle output to Excel
         *
         =MESSAGEBOX("exporting to "+m.toOptions.cOutputFile)
         RETURN .F.   && suppress the default behavior
      ELSE
         RETURN .T.   && continue with the default behavior
      ENDIF
 
  ENDPROC

ENDDEFINE

Code Block

language	vb
title	Example 2
linenumbers	true

SET PATH TO xfrxlib
SET CLASSLIB TO xfrxlib
 
LOCAL m.loPreview, m.loSession, m.loExtensionHandler
 
m.loExtensionHandler = CREATEOBJECT("myExtensionHandler")
 
m.loPreview = CREATEOBJECT("frmMPPreviewer")
m.loSession=EVALUATE([xfrx("XFRX#LISTENER")])
 
*
* create a memory XFF file
*
m.lnRetVal = m.loSession.SetParams(,,,,,,"XFF")
IF m.lnRetVal = 0
   SELECT * ;
     FROM customers INNER JOIN orders ON customers.customerid = orders.customerid ;
                    INNER JOIN orderdetails ON orders.orderid = orderdetails.orderid ;
     ORDER BY customers.companyname, customers.customerID, orders.orderID ;
     INTO CURSOR custlist
           
   REPORT FORM custlist OBJECT loSession
ENDIF
 
*
* assign the extension handler
*
m.loPreview.setExtensionHandler(loExtensionHandler)
*
* preview the report
*
m.loPreview.previewXFF(m.loSession.oxfdocument)
m.loPreview.show(1)
 
DEFINE CLASS myExtensionHandler AS CUSTOM
   PROCEDURE Print
      LPARAMETERS m.toXFF
      RETURN .t. && continue with the default behavior
   ENDPROC
 
   PROCEDURE Export
      LPARAMETERS m.toXFF
      *
      * now you can process the XFF file
      *
      RETURN .F. && override the default behavior
   ENDPROC
ENDDEFINE

Code Block

language	vb
title	BeforeExport & AfterExport Example
linenumbers	true

USE demoreps\invoices ORDER customer
LOCAL m.loSession, m.lnRetval, m.loXFF, m.loPreview, m.loScripts
m.loSession=EVALUATE([xfrx("XFRX#LISTENER")])
m.lnRetVal = m.loSession.SetParams(,,,,,,"XFF") && no name = just in memory
IF m.lnRetVal = 0
   REPORT FORM demoreps\invoices object m.loSession
   *
   * the XFRX#DRAW object reference is stored in oxfDocument property
   *
   m.loXFF = m.loSession.oxfDocument
   *
   * initialize the previewer 
   *
   SET PATH TO xfrxlib
   SET CLASSLIB TO xfrxlib ADDITIVE 
   m.loPreview = CREATEOBJECT("frmMPPreviewer")
   *
   * setup the extension handler
   *
   m.loPreview.oExtensionHandler = CREATEOBJECT("SampleExtensionHandler")
   m.loPreview.windowtype = 1 
   m.loPreview.iTool = 2 && embedded toolbar
   m.loPreview.PreviewXFF(m.loXFF)
   m.loPreview.show(1)
ENDIF

DEFINE CLASS SampleExtensionHandler as Custom

   PROCEDURE BeforeExport
      LPARAMETERS m.toSession, m.toExportParameters

      m.toSession.setAuthor("Martin") && set the document author property
      IF m.toExportParameters.cTarget = "XLS" && (XLS or XLSPLAIN)
         m.toSession.SetOtherParams("DISPLAY_GRID_LINES",.F.) && do not display gridlines in excel
      ENDIF
   ENDPROC

   PROCEDURE AfterExport
      LPARAMETERS m.toSession, m.toOptions
      IF m.toOptions.cTarget = "XLS"
         *COPY FILE (m.toOptions.coutputfile) TO ([anybackupfolder]\[anyfile.xls])
      ENDIF
   ENDPROC

ENDDEFINE

Code Block

title	KeyPress example
linenumbers	true

USE demoreps\invoices ORDER customer
LOCAL m.loSession, m.lnRetval, m.loXFF, m.loPreview, m.loScripts
m.loSession=EVALUATE([xfrx("XFRX#LISTENER")])
m.lnRetVal = m.loSession.SetParams(,,,,,,"XFF") && no name = just in memory
IF m.lnRetVal = 0
   REPORT FORM demoreps\invoices OBJECT m.loSession
   *
   * the XFRX#DRAW object reference is stored in oxfDocument property
   *
   m.loXFF = m.loSession.oxfDocument
   *
   * initialize the previewer 
   *
   SET PATH TO xfrxlib
   SET CLASSLIB TO xfrxlib ADDITIVE 
   m.loPreview = CREATEOBJECT("frmMPPreviewer")
   *
   * setup the extension handler
   *
   m.loPreview.oExtensionHandler = CREATEOBJECT("SampleExtensionHandler")
   m.loPreview.windowtype = 1 
   m.loPreview.iTool = 2 && embedded toolbar
   m.loPreview.PreviewXFF(loXFF)
   m.loPreview.show(1)
ENDIF

DEFINE CLASS SampleExtensionHandler AS CUSTOM

   PROCEDURE KeyPress(m.loXFCont, m.nKeyCode, m.nShiftAltCtrl)
      * hotkey for print P (112-p, 80-P)
      IF INLIST(m.nKeyCode, 112, 80)
         m.loXFCont.Print()
      ENDIF
   ENDPROC
ENDDEFINE

Showing / hiding bookmarks

The bookmark panel behavior is controlled by the iBook property:

Property

Usage

iBook

Controls if the bookmark should be displayed in the previewer. The allowed values are:

-1 = Disable bookmarks
0 = Enable bookmarks but hide them (users need to click on the bookmark button to see them)
1 = Enable bookmarks, always showing them (default)
2 = Enable bookmarks, but show or hide them automatically based on whether or not there are bookmarks defined in the report to preview (default)

Showing / hiding previewer toolbars

There are two toolbars in the previewer control – one is placed at the bottom of the control, the other one is available as a floating toolbar panel, which by default docks at the top of the main window, or, alternatively, as an “embedded toolbar”. All three classes implement iTool and ShowStatus properties that control visibility of the toolbars:

Property	Usage	XFRX version
classMainToolbar	The class name of the toolbar. The default value is “xfrxToolbar”. You can create a child of the default xfrxToolbar class (defined in xfrxlib.vcx) and use this property to instruct the previewer to use your class rather than the default one. This property works for the “real” toolbar – if iTool property is 0 or 1. if iTool is set to 2, cmdEmbeddedToolbar container class is used as the “embedded” toolbar.
ClassMainStatusBar	The class name of the status bar or embdded toolbar. The default value is “cntembeddedtoolbar”. You can create a child of the default cntembeddedtoolbarr class (defined in xfrxlib.vcx) and use this property to instruct the previewer to use your class rather than the default one.	17.3
iTool	Controls the visibility of the toolbar at the top. The allowed values are: -1 = Disable toolbar 0 = The toolbar will be enabled but hidden. It can be invoked via right click shortcut menu 1 = The toolbar will be enabled and visible. (default) 2 = The toolbar will be displayed as embedded to the form (available only in cntXFRXMultiPage and frmMPPreviewer classes.
ShowStatus	Controls the visibility of the toolbar at the status bar of the previewer container. The allowed values are: .T. = show the toolbar (default) .F. = hide the toolbar

Displaying progress bar

Property	Usage
oprogress	The object instance of XFRX progress bar

Code Block

linenumbers	true

USE demoreps\invoices ORDER customer
LOCAL m.loSession, m.lnRetval, m.loXFF, m.loPreview, m.loScripts
m.loSession=EVALUATE([xfrx("XFRX#LISTENER")])
m.lnRetVal = m.loSession.SetParams(,,,,,,"XFF") && no name = just in memory
IF m.lnRetVal = 0
   REPORT FORM demoreps\invoices OBJECT m.loSession
   *
   * the XFRX#DRAW object reference is stored in oxfDocument property
   *
   m.loXFF = m.loSession.oxfDocument
   *
   * initialize the previewer 
   *
   SET PATH TO xfrxlib
   SET CLASSLIB TO xfrxlib ADDITIVE 
   m.loPreview = CREATEOBJECT("frmMPPreviewer")
   *
   * setup the extension handler
   *
   m.loPreview.oExtensionHandler = CREATEOBJECT("SampleExtensionHandler")
   m.loPreview.oprogress=createobject("progress")
   m.loPreview.PreviewXFF(loXFF)
   m.loPreview.show(1)
ENDIF

DEFINE CLASS progress AS CUSTOM
   PROCEURE updateProgress
      LPARAM m.ta,m.tb, m.tc
      WAIT WINDOW NOWAIT "Page #: "+ALLT(STR(m.tb))+" Report #: "+ALLT(STR(m.ta))+" ("+ALLT(STR(m.tc))+"%)"
   ENDPROC
ENDDEF

Using frmMPPreviewer class

This class serves as a standalone (fullscreen) previewer window. All you need to do to make it work is to pass it a reference to the XFF file to preview, using the previewXFF method, as described in Controlling multi-tab preview features paragraph above. (If you are not sure how to create a XFF file reference, please read chapters 17.0: Initializing the XFRX#DRAW class instance and 16.3: Creating temporary XFF files). Here is a very simple “Hello World” example:

Code Block

linenumbers	true

LOCAL m.loPreview
SET CLASSLIB TO XFRXLIB.VCX ADDITIVE 
m.loPreview = CREATEOBJECT("frmMPPreviewer") && create the previewer object
m.loPreview.previewXFF(m.loXFF)              && loXFF is XFF file reference
m.loPreview.show(1)                          && show the form as modal

Info
Make sure to set all properties (like iTool, ShowStatus, etc.) before you call PreviewXFF(…) otherwise they won’t be used.

Using cntXFRXMultiPage class

Add an instance of cntXFRXMultiPage class (of XFRXLIB.VCX) into your form. Adjust the size of the cntXFRXMultiPage class object container as you need. The previewer, including the status bar, icons and scroll bars will be displayed in the container. If you resize the container in runtime, its content is automatically adjusted.
When the form is about to be released, the cntXFRXMultiPage class instance needs to do some cleanup. To enable that please call the class instance’s clearLink() method from form’s destroy method:
Code Block
linenumbers true
PROCEDURE Destroy Thisform.cntXFRX.clearLink() ENDPROC
When running the form, make sure the XFRXLIB.VCX class library is referenced in SET CLASSLIB command:
Code Block
SET CLASSLIB TO XFRXLIB.VCX ADDITIVE
Call the PreviewXFF method to preview a XFF file, as described in Controlling multi-tab preview features paragraph above.
By default, cntXFRXMultiPage is using an instance of the XFCont class for each page. Should you like to make it use a different class (eg. a subclass of XFCont) put the class name to the ClassPreviewPage property of the cntXFRXMultiPage instance.

Using XFCont class

Add an instance of XFCONT class (of XFRXLIB.VCX) into your form. Adjust the size of the XFCONT class container as you need. The previewer, including the status bar, icons and scroll bars will be displayed in the container. If you resize the container in runtime, its content is automatically adjusted.
When the form is about to be released, the XFCONT class instance needs to do some cleanup. To enable that please call the XFCont class instance’s clearLink() method from form’s destroy method:

PROCEDURE
Code Block
linenumbers true
PROCEDURE Destroy Thisform.cntXFRX.clearLink() ENDPROC
When running the form, make sure the XFRXLIB.VCX class library is referenced in SET CLASSLIB command:
Code Block
SET CLASSLIB TO XFRXLIB.VCX ADDITIVE

VFP 8.0 approach

In VFP 8.0, there are two options how to preview report in the previewer. The options differ in the calling mechanism, although internally they both work exactly the same.

Generating the “CNT” output type

The approach is using the standard syntax of calling XFRX, without explicitly using the XFRX#DRAW class (although it is used in the background). You cannot open an existing XFF file with this approach – you always need to run a report that will be previewed.

Do not send anything as the output file name
Use “CNT” as the output type parameter in the SetParams method call
Call Reset method of the previewer container class
Call SetOtherParams method of the XFRXSession class instance with the reference of XFCont instance as a parameter

Example:

Code Block

language	vb
linenumbers	true

LOCAL m.loSession, m.lnRetval loSession= xfrx("XFRX#INIT") m.lnRetVal = m.loSession.SetParams(,,,,,,"CNT") IF m.lnRetVal = 0 * * we are assuming the XFCont container is * available as thisform.cntXFRX * Thisform.cntXFRX.reset() m.loSession.setotherparams(Thisform.cntXFRX) m.loSession.ProcessReport("report") m.loSession.finalize() ENDIF

Using the XFRX#DRAW class

The advantage of this method is that you can preview an existing XFF file – the XFF file is opened and “converted” to “CNT” output type via the TransformReport method:

Example:

Code Block

language	vb
linenumbers	true

LOCAL m.loSession m.loSession= xfrx("XFRX#INIT") Thisform.oReport = xfrx("XFRX#DRAW") IF Thisform.oReport.openDocument("file.xff") Thisform.cntXFRX.reset() m.lnRetVal = m.loSession.SetParams(,,,,,,"CNT") IF m.lnRetVal = 0 m.loSession.setOtherParams(Thisform.cntXFRX) m.loSession.TransformReport(Thisform.oReport) ENDIF ENDIF

VFP 9.0 Approach

In VFP 9.0 the logic is the same, just the syntax is a little bit different – the reference to the XFCont object is copied to XFRXPreviewer property of the XFRXListener class instance and then previewReport method with the XFRX#DRAW reference as parameter is called:

Code Block

language	vb
linenumbers	true

LOCAL m.loSession
m.loSession= xfrx("XFRX#LISTENER")
Thisform.oReport = xfrx("XFRX#DRAW")
IF Thisform.oReport.openDocument("file.xff")
   Thisform.cntXFRX.reset()
   m.loSession.XFRXPreviewer = Thisform.cntXFRX
   m.loSession.previewReport(Thisform.oReport)
ENDIF

Hyperlink decoration

A new property has been added to the XFCont, cntXFRXMultipage and frmMPPreviewer classes: UnderlineHyperlinksOnPrint. You can use the following values:
0 - no decoration for hyperlinks
1 - display "normal" hyperlinks in blue, but do not decorate custom event hyperlinks (green)
2 - (default value) decorate both blue and green hyperlinks

To support this in the print output, the PrintDocument method of the XFRX#DRAW class has a new parameter, tnUnderlineHyperlinksOnPrint, with the same values and logic.

Custom buttons

This feature is implemented using the extension handler mechanism: A new method is now supported - ToolbarOnInit, which is invoked at the time the toolbar is initialized. In this method the extension handler can add new buttons to the previewer and their click events can be bound with other methods in the extension handler. A new property is now supported, too - oPreviewContainer. If it is available, the previewer will automatically fill it with the XFCont object reference for easier access to the previewer properties in the custom buttons click event methods.

Example:

Code Block

language	vb
linenumbers	true

USE demoreps\sales
LOCAL m.loSession, m.lnRetval, m.loXFF, m.loPreview, m.loScripts
m.loSession=EVALUATE([xfrx("XFRX#LISTENER")])
m.lnRetVal = m.loSession.SetParams(,,,,,,"XFF") && no name = just in memory
IF m.lnRetVal = 0
   REPORT FORM demoreps\sales OBJECT m.loSession
   *
   * the XFRX#DRAW object reference is stored in oxfDocument property
   *
   m.loXFF = m.loSession.oxfDocument
   *
   * initialize the previewer
   *
   SET PATH TO xfrxlib
   SET CLASSLIB TO xfrxlib ADDITIVE
   m.loPreview = CREATEOBJECT("frmMPPreviewer")
   *
   * setup the extension handler
   *
   m.loPreview.oExtensionHandler = CREATEOBJECT("SampleExtensionHandler")
   m.loPreview.windowtype = 1
   m.loPreview.iTool = 2 && embedded toolbar
   *m.loPreview.iTool = 1 && standard toolbar
   m.loPreview.PreviewXFF(m.loXFF)
   m.loPreview.show(1)
ENDIF
 
DEFINE CLASS SampleExtensionHandler AS CUSTOM
 
   oPreviewContainer = .NULL.
 
   PROCEDURE ToolbarOnInit
      LPARAMETERS m.toToolbar
      LOCAL m.button
      IF m.toToolbar.AddObject("mybutton", "commandbutton")
         BINDEVENT(m.toToolbar.mybutton, "click" , This, "ButtonClicked")                       
         m.toToolbar.mybutton.tabindex = 1
         m.toToolbar.mybutton.Visible = .t.
         IF UPPER(m.totoolbar.BaseClass)!="TOOLBAR"
            m.toToolbar.mybutton.left = m.toToolbar.cmdQuit.left
            m.toToolbar.cmdQuit.left = m.toToolbar.mybutton.left + m.toToolbar.mybutton.width
         ENDIF                           
      ENDIF
   ENDPROC
 
   PROCEDURE ButtonClicked
      LOCAL m.lcString
      m.lcString = "This.oPreviewContainer.Name: "+This.oPreviewContainer.Name+CHR(13)
      m.lcString = m.lcString + "current page: "+TRANSFORM(This.oPreviewContainer.nPageNo)+CHR(13)
      m.lcString = m.lcString + "XFRX#DRAW Object: "+This.oPreviewContainer.oXFRXWriter.Name+CHR(13)
      m.lcString = m.lcString + "Page count: "+TRANSFORM(This.oPreviewContainer.oXFRXWriter.PageCount)+CHR(13)
      WAIT WINDOW m.lcString
   
      *This.oPreviewContainer.oXFRXWriter.PrintDocument(...)
      *This.oPreviewContainer.oXFRXWriter.SavePicture(...)
   ENDPROC

ENDDEFINE

Versions Compared

Old Version 2

New Version 3

Key

Default settings

Common methods and properties

Controlling multi-tab preview features

Registering an extension handler

Showing / hiding bookmarks

Showing / hiding previewer toolbars

Displaying progress bar

Using frmMPPreviewer class

Using cntXFRXMultiPage class

Using XFCont class

Hyperlink decoration

Custom buttons